Database function to calculate total value

Excel Project- Return Excel Sheet Attached- Instructions Attached Separate

p 1 Download start file

In this project, you will create a worksheet to analyze inventory and financial data for a sporting goods store.

Skills needed to complete this project:

• Calculating Totals with SUMPRODUCT • Finding the Middle Value with MEDIAN • Finding the Most Common Value(s) with MODE.SNGL and MODE.MULT • Using SUMIF and SUMIFS • Using AVERAGEIF and AVERAGEIFS • Using COUNTIF and COUNTIFS • Using Database Functions • Finding Data with MATCH and INDEX • Managing Errors with the IFERROR Function • Ranking Values in a Dataset with RANK.EQ and RANK.AVG • Analyzing Complex Formulas Using Evaluate Formula • Calculating Future Value with the FV Function • Calculating the Number of Payments with NPER • Rounding with Functions • Using NPV to Calculate Present Value when Payments Are Variable • Creating a Depreciation Schedule

1. Open the start file EX2016-SkillReview-6-2. The file will be renamed automatically to include your name. 2. If the workbook opens in Protected View, click the Enable Editing button in the Message Bar at the top

of the workbook so you can modify the workbook. 3. Start with the Analysis worksheet. Use the SUMPRODUCT function to calculate the total value of the

inventory. Use the values in the Selling Price column and the corresponding values in the Stock column as the Array arguments. a. Click cell B2.

b. Type =SUMPRODUCT(

c. Click the Inventory sheet tab, and then click and drag to select cells G3:G25.

d. Type , and then click and drag to select cells H3:H25.

e. Type ) and press [Enter].

f. The formula should look like this:

=SUMPRODUCT(Inventory!G3:G25,Inventory!H3:H25)

4. Enter a formula to calculate the average selling price.

a. Click cell D2.

b. Type =AVERAGE(

c. Click the Inventory sheet tab, and then click and drag to select cells G3:G25.

d. Press [Enter]. The formula should look like this: =AVERAGE(Inventory!G3:G25)

5. Enter a formula to find the middle selling price.

a. Click cell E2.

b. Type =MEDIAN(

1 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

c. Click the Inventory sheet tab, and then click and drag to select cells G3:G25.

d. Press [Enter]. The formula should look like this: =MEDIAN(Inventory!G3:G25)

6. Enter a formula to find the most common selling price.

a. Click cell F2.

b. Type =MODE.SNGL(

c. Click the Inventory sheet tab, and then click and drag to select cells G3:G25.

d. Press [Enter]. The formula should look like this: =MODE.SNGL(Inventory!G3:G25)

7. What if there are multiple selling prices that are the most common? Enter an array formula in cells G2:G5

to find up to four most common selling prices.

a. Select cells G2:G5.

b. Type =MODE.MULT(

c. Click the Inventory sheet tab, and then click and drag to select cells G3:G25.

d. Press [Ctrl]+[Shift]+[Enter]. The formula should look like this:

{=MODE.MULT(Inventory!G3:G25)}

8. Use the SUMIFS function to calculate the total number of blue shoes in inventory. Use the values in the

Cost column as the Sum_range argument. Use the values in the Item Description column as the Criteria_range1

argument and use the criteria *shoes to find all items that end in the word shoes. Use the values in the Color

column as the Criteria_range2 argument and use the criteria blue.

a. Click cell B3.

b. On the Formulas tab, in the Function Library group, click the Math & Trig button and select SUMIFS.

c. In the Function Arguments dialog, verify that the cursor is in the Sum_range argument box. Click the

Inventory sheet tab, and click and drag to select cells H3:H25.

d. In the Function Arguments dialog, press [Tab] to move to the Criteria_range1 argument box.

e. Click the Inventory sheet tab, and click and drag to select cells A3:A25.

f. In the Function Arguments dialog, press [Tab] to move to the Criteria1 argument box.

g. Type "*shoes" to find any text string that ends with the word shoes.

h. Press [Tab]. Verify that the cursor is in the Criteria_range2 argument box.

i. Click the Inventory sheet tab, and click and drag to select cells C3:C25.

j. In the Function Arguments dialog, press [Tab] to move to the Criteria2 argument box.

k. Type: "blue"

l. Click OK.

m. The formula should look like this: =SUMIFS(Inventory!H3:H25,Inventory!A3:A25,"*shoes",Inventory!C3:C25,"bl

ue")

2 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

9. Use the AVERAGEIFS function to find the average selling price of blue shoes in inventory. Use the values

in the Selling Price column as the Average_range argument. Use the values in the Item Description column as

theCriteria_range1 argument and use the criteria *shoes to find all items that end in the word shoes. Use the

values in the Color column as the Criteria_range2 argument and use the criteria blue.

a. Click cell B4.

b. On the Formulas tab, in the Function Library group, click the More Functions button, point to

Statistical, and select AVERAGEIFS.

c. In the Function Arguments dialog, verify that the cursor is in the Average_range argument box. Click the

Inventory sheet tab, and click and drag to select cells G3:G25.

d. In the Function Arguments dialog, press [Tab] to move to the Criteria_range1 argument box.

e. Click the Inventory sheet tab, and click and drag to select cells A3:A25.

f. In the Function Arguments dialog, press [Tab] to move to the Criteria1 argument box.

g. Type "*shoes" to find any text string that ends with the word shoes.

h. Press [Tab]. Verify that the cursor is in the Criteria_range2 argument box.

i. Click the Inventory sheet tab, and click and drag to select cells C3:C25.

j. In the Function Arguments dialog, press [Tab] to move to the Criteria2 argument box.

k. Type: "blue"

l. Click OK.

m. The formula should look like this:

=AVERAGEIFS(Inventory!G3:G25,Inventory!A3:A25,"*shoes",Inventory!C3:C25,"blue")

10. Use the COUNTIFS function to find the number of blue shoe inventory items. Use the values in the Item

Description column as the Criteria_range1 argument and use the criteria *shoes to find all items that end in the

word shoes. Use the values in the Color column as the Criteria_range2 argument and use the criteria blue.

a. Click cell B5.

b. On the Formulas tab, in the Function Library group, click the More Functions button, point to

Statistical, and select COUNTIFS.

c. In the Function Arguments dialog, verify that the cursor is in the Criteria_range1 argument box.

d. Click the Inventory sheet tab, and click and drag to select cells A3:A25.

e. In the Function Arguments dialog, press [Tab] to move to the Criteria1 argument box.

f. Type "*shoes" to find any text string that ends with the word shoes.

g. Press [Tab]. Verify that the cursor is in the Criteria_range2 argument box.

h. Click the Inventory sheet tab, and click and drag to select cells C3:C25.

i. In the Function Arguments dialog, press [Tab] to move to the Criteria2 argument box.

j. Type: "blue"

k. Click OK.

3 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

l. The formula should look like this:

=COUNTIFS(Inventory!A3:A25,"*shoes",Inventory!C3:C25,"blue")

11. Now use database functions to analyze inventory data. This method gives you more flexibility in your

analysis. Once you set up the formulas, you can change the criteria in the worksheet without changing the

formulas. The InventoryDB named range has been created for you to use as the Database argument. It

references A2:H25 on the Inventory worksheet. Notice this named range includes the label row.

Use the DAVERAGE database function to calculate the average selling price for all items with the word

football in the item description. Use the wildcard character * before and after the word football to find all

item descriptions with football anywhere in the text. Use the column label Selling Price as the Field argument.

Remember to enclose the column label in quotation marks. Set up the criteria range.

a. In cell D8, type: Item Description

b. In cell D9, type: *Football*

c. Click cell B9 where you will enter the formula.

d. On the Formulas tab, in the Function Library group, click the Insert Function button.

e. If necessary, expand the Or select a category list, and select Database.

f. Double-click DAVERAGE to open the Function Arguments dialog.

g. In the Database argument box, type the range name: InventoryDB

h. In the Field argument box, type the column label: "Selling Price"

i. Click in the Criteria argument box and then click and drag to select cells D8:D9.

j. Click OK.

k. The formula should look like this:

=DAVERAGE(InventoryDB,"Selling Price",D8:D9)

12. Use the DCOUNT database function to calculate the number of items in stock where the item description

includes the word Football and the selling price is less than $20. Use the wildcard character * before and

after the word Football to find all item descriptions with Football anywhere in the text. Use the column label

Stock as the Field argument. Remember to enclose the column label in quotation marks.

a. Set up the criteria range.

i. In cell D11, type: Item Description

ii. In cell D12, type: *Football*

iii. In cell E11, type: Selling Price

iv. In cell E12, type: <20

b. Click cell B12 where you will enter the formula.

c. On the Formulas tab, in the Function Library group, click the Insert Function button.

d. If necessary, expand the Or select a category list, and select Database.

4 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

e. Double-click DCOUNT to open the Function Arguments dialog.

f. In the Database argument box, Type the range name: InventoryDB

g. In the Field argument box, type the column label: "Stock"

h. Click in the Criteria argument box and then click and drag to select cells D11:E12.

i. Click OK.

j. The formula should look like this: =DCOUNT(InventoryDB,"Stock",D11:E12)

13. Now use MATCH and INDEX to look up the item description, quantity in stock, and selling price

of an item based on the inventory number. The Inventory named range has been created for you to use

in these formulas. It references A3:H25 on the Inventory worksheet. Notice this named range does not

include the label row.

First, use MATCH to find the row position for the item listed in cell B15. Remember, the

Lookup_array argument must be a single column. Require an exact match. Use absolute references

so you can copy the formula.

a. Click cell B16.

b. On the Formulas tab, in the Function Library group, click the Lookup & Reference button, and

select MATCH.

c. Use an absolute reference to cell B15 for the Lookup_value argument. Type: $B$15 and then

press [Tab].

d. Verify that the cursor is in the Lookup_array argument box. Click the Inventory sheet tab and click

and drag to select cells B3:B25. Edit the cell references to be absolute.

e. In the Match_type argument box, type: 0

f. Click OK.

g. The formula should look like this: =MATCH($B$15,Inventory!$B$3:$B$25,0)

14. Now add an INDEX function around the MATCH function to find the item description (column 1)

for the row position identified by the MATCH function. Use the named range Inventory as the

Array argument.

a. If necessary, select cell B16 again, and then click in the formula bar so you can edit the formula.

b. After the =, type: INDEX(Inventory,

c. Move the cursor to the end of the formula and type: ,1)

d. Press [Enter].

e. The formula should now look like this:

=INDEX(Inventory,MATCH($B$15,Inventory!$B$3:$B$25,0),1)

5 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

15. Add an IFERROR function around the INDEX function to hide any error messages by displaying an

empty text string ("").

a. If necessary, select cell B16 again, and then click in the formula bar so you can edit the formula.

b. After the =, type: IFERROR(

c. Move the cursor to the end of the formula and type: ,"")

d. Press [Enter].

e. The formula should now look like this:

=IFERROR(INDEX(Inventory,MATCH($B$15,Inventory!$B$3:$B$25,0),1),"")

16. Copy the formula from cell B16 to cells B17:B18.

17. Modify the formula in cell B17 to use 8 as the Column_num argument for the INDEX function. The

formula should look like this:

=IFERROR(INDEX(Inventory,MATCH($B$15,Inventory!$B$3:$B$25,0),8),"")

18. Modify the formula in cell B18 to use 6 as the Column_num argument for the INDEX function. The

formula should look like this:

=IFERROR(INDEX(Inventory,MATCH($B$15,Inventory!$B$3:$B$25,0),6),"")

19. If necessary, apply the Accounting Number Format to cell B18.

20. Enter a formula using RANK.EQ to calculate the ranking of this item’s price.

a. Click cell B19.

b. On the Formulas tab, in the Function Library group, click the More Functions button, point to

Statistical, and select RANK.EQ.

c. In the Number argument box, type: 1.15 and then press [Tab].

d. Verify that the cursor is in the Ref argument box. Click the Inventory sheet tab and click and drag to

select cells F3:F25.

e. Click OK.

f. Save the file.

21. If you are having trouble with these formulas, use the Evaluate Formula feature to review the results of

the nested formulas.

a. Select the cell containing the formula you want to evaluate.

b. On the Formulas tab, in the Formula Auditing group, click the Evaluate Formula button.

c. Use the Step In, Evaluate, and Step Out buttons as necessary until you have a clear understanding of how

the nested INDEX and MATCH formulas work together.

6 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

22. Hank’s Sporting Goods is considering taking out a $20,000 loan to pay for inventory. The details of that

loan are shown on the Financials worksheet in cells C2:D6. You will help Hank calculate how much money

he would make if he invested those same monthly payments in a money market account instead. Calculate

the theoretical future value of the same amount deposited monthly in a money market account.

a. Switch to the Financials worksheet.

b. Click cell D9.

c. On the Formulas tab, in the Function Library group, click the Financial button, and select FV.

d. Enter the Rate argument, referring to the money market interest rate in cell B4. The rate is expressed as

an annual interest rate, and payments will be monthly, so divide the interest rate by 12: B4/12

e. Enter the Nper argument, referring to cell D5. There will be monthly payments, so multiple the

number of years by 12: D5*12

f. Enter the Pmt argument referring to the cell showing the monthly payment amount for the loan: D4

Notice that the loan payment is already expressed as a negative number so there is no need to alter the

Pmt argument.

g. There is no value in the investment prior to the first investment period, so you can skip the Pv

argument.

h. Deposits would be scheduled for the beginning of each payment period. Enter the appropriate Type

argument: 1

i. Click OK. The formula in cell D10 should look like this: =FV(B4/12,D5*12,D4,,1)

j. Save the file.

23. Hank would like to consider another loan option with the same loan amount and the same interest rate.

How many months would it take to pay off the loan if he paid a flat $900 every month?

a. Click cell D13. On the Formulas tab, in the Function Library group, click the Financial button, and select

NPER.

b. Enter the Rate argument, referring to the loan interest rate in cell B3. The rate is expressed as an

annual interest rate, and payments will be monthly, so divide the interest rate by 12: B3/12

c. Enter the Pmt argument referring to the cell showing the new monthly payment amount for

the loan: D12

Notice that the loan payment is already expressed as a negative number so there is no need to alter

the Pmt argument.

d. Enter the Pv argument referring to the original loan amount in cell D3.

e. The loan will be completely paid off, so you can skip the Fv argument.

f. Payments would be applied at the end of each payment period, so you can skip the Type argument.

g. Click OK. The formula in cell D14 should look like this: =NPER(B3/12,D12,D3)

7 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

24. Hank is easily confused by too many digits after the decimal point, so add a ROUND function to round

the number of months to zero decimal places.

a. If necessary, click cell D13 again.

b. In the formula bar, add the ROUND function using the existing FV function as the Number argument

and 0 as the Num_digits argument. The formula should now look like this:

=ROUND(NPER(B3/12,D12,D3),0)

25. Hank has another financial question for you. He needs to decide between three equipment purchase

options. Option 1 is the least expensive and will require minimal repairs. It will generate the lowest

increase in revenue. Option 2 is $10,000 more than Option 1 and will generate a higher increase in

revenue, but it will require significant repair in year 5 and will begin declining in productivity in year 7.

Option 3 is the most expensive. It will also generate the highest increase in revenue. However, it will

require more frequent and expensive repairs than the other two options.

Enter the formula to calculate net present value for Option 1 using the revenue schedule in cells B9:B18.

Use a discount rate of 1.5%.

a. Click the Equipment Decision worksheet.

b. Click cell B5.

c. Type: =NPV(

d. Type: 1.5%,

e. Click and drag to select cells B9:B18.

f. Type ) and then press [Enter] to complete the formula: =NPV(1.5%,B9:B18)

26. Copy the formula in cell B5 to cells C5 and D5 to calculate the NPV for Option 2 and Option 3.

27. Format cells B5:D5 with the Accounting Number Format.

28. Calculate the true cost of the investment by adding the initial investment (the purchase cost) to the

calculated NPV amount:

a. In cell B6 enter the formula as follows: =B4+B5

b. Copy the formula in cell B6 to cells C6 and D6.

29. Use the Thick Outside Borders option to place a border around cells D3:D6 to highlight the best

investment option.

30. Now calculate two alternative depreciation schedules for the selected equipment option. First, set up the

values that will be used for the common arguments Cost, Life, and Salvage.

a. In cell G3, enter a reference to cell D4. For the depreciation schedule, the cost value should be a

positive number, so precede the cell reference with a - character: =-D4

b. In cell G4, enter the useful life of the equipment: 10

c. In cell G5, enter the salvage value of the equipment. Calculate this as 20 % of the cost: =G3*0.2

8 | Page Skill Review 6.2 Last Updated 11/21/17

A Skills Approach: Excel 2016 Chapter 6: Exploring Advanced Functions

31. In cell J4, enter the formula to calculate depreciation for year 1 using the declining balance method.

a. On the Formulas tab, in the Function Library group, click the Financial button, and then select DB.

b. Enter the Cost argument as an absolute cell reference so the reference will not update when you copy

the formula: $G$3

c. Enter the Salvage argument as an absolute cell reference so the reference will not update when you

copy the formula: $G$5

d. Enter the Life argument as an absolute cell reference so the reference will not update when you copy

the formula: $G$4

e. Enter the Period argument as a relative cell reference, so the reference will update when you copy the

formula: I4

f. The equipment will be in use for 12 months during the first year, so you can skip the Month argument.

g. Click OK. The formula in cell J4 should look like this: =DB($G$3,$G$5,$G$4,I4)

h. Copy the formula to J5:J13.

32. In cell K4, enter the formula to calculate depreciation for year 1 using the straight-line method.

a. On the Formulas tab, in the Function Library group, click the Financial button, and then select SLN.

b. Enter the Cost argument as an absolute cell reference so the reference will not update when you copy

the formula: $G$3

c. Enter the Salvage argument as an absolute cell reference so the reference will not update when you

copy the formula: $G$5

d. Enter the Life argument as an absolute cell reference so the reference will not update when you copy

the formula: $G$4

e. Click OK. The formula in cell K4 should look like this: =SLN($G$3,$G$5,$G$4)

f. Copy the formula to K5:K13. Notice that the straight-line method returns the same depreciation value

for each period in the schedule.

33. Save and close the workbook. Step 2 Upload & Save

Step 3 Grade my Project

34. Upload and save your project file.

35. Submit project for grading.

9 | Page Skill Review 6.2 Last Updated 11/21/17

Skill Review 6.2